.bra {
.ket }
.key USER/A,PASSWORD/A,GROUP/A,SUBJECT/A,POSTTO/A,DAYS/A,MAXUSERS/A,MAXSUBJECTS/A

; ------------------------------------------------------------------------
;
set VERSION $VER: AutoStat V1.06 (01 Dec 1993)
;
; Function:
;
; builds statistics using UMSMailStat and posts them automagically into
; a user defined group.
;
; All arguments _must_ be given!
;
; arguments:
;
; USER, PASSWORD  - of the user posting the stats
; SUBJECT         - subject of the message to be written
; POSTTO          - group to where the message will be posted
;
; UMSMailStat specific arguments:
;
; GROUP           - group about which the stats will be built
; DAYS            - only for the message of the past DAYS days.
; MAXUSERS        - authorhitlist contains MAXUSERS entries
; MAXSUBJECTS     - subjectlist contains MAXSUBJECTS entries
;
; ------------------------------------------------------------------------

echo "[1m$VERSION[0m by Olaf Peters*N"

IF EXISTS t:AutoStat.tmp
  delete >NIL: t:AutoStat.tmp
ENDIF

; messagetext

echo >>t:AutoStat.tmp "Group = {POSTTO}*NSubject = {SUBJECT}*NNoUpdate*N--------------*N" NOLINE
ums:bin/UMSMailStat >>t:AutoStat.tmp {USER} {PASSWORD} GROUP={GROUP} DAYS={DAYS} MAXUSERS={MAXUSERS} MAXSUBJECTS={MAXSUBJECTS} ENGLISH

; output to stdout

echo "Sende diese Nachricht:"
type t:AutoStat.tmp

; send the message

ums:bin/sumsWrite {USER} {PASSWORD} <t:AutoStat.tmp


